Запуск скриптов WSH на удалённых компьютерах с помощью объекта WshRemote

С помощью объектов WshController и WshRemote сценарии Windows Script Host можно запускать не только на локальной машине, но и на удалённых компьютерах, имеющихся в сети. При этом исполняемый сценарий не будет явно копироваться на жёсткий диск удалённого компьютера, а работа будет происходить по протоколу DCOM (Distributed COM). Примеры кода WSH в настоящей статье будут приводиться на языке VBScript.

Для успешного запуска должны быть соблюдены следующие требования:

на локальной и удалённой машинах должны быть установлены операционные системы не ниже Windows NT(SP3)/2000/XP и Windows Script Host версии не ниже 5.6;
пользователь, который запускает сценарий, должен входить в группу локальных администраторов на той машине, где должен выполняться сценарий;
на удалённой машине должен существовать параметр реестра HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Script Host\Settings\Remote, равный 1 (разрешение на запуск удалённых сценариев для компьютера);
на удалённой машине может существовать параметр реестра HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows Script Host\Settings\Remote, равный 1 или 0 (разрешение или запрет на запуск удалённых сценариев для пользователя); на удалённой машине также может существовать параметр реестра HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Script Host\Settings\IgnoreUserSettings, равный 1 или 0 (игнорировать параметры пользователя или нет); в зависимости от последнего параметра принимается во внимание разрешение или запрет на запуск удалённых сценариев для пользователя;
вероятно, для успешной работы придётся предварительно выполнить на удалённой машине такую команду:
```
wscript.exe -regserver
```
эта команда зарегистрирует wscript.exe как "внепроцессный" COM-сервер (out of process COM server), который работает в процессе, отличном от клиентского;
возможно, для успешной работы придётся предварительно отконфигурировать настройки протокола DCOM на удалённой машине (запустите dcomcnfg и найдите элемент WSHRemote), указав конкретного пользователя/пароль для запуска; для разрешения проблем обращайтесь к сайту Microsoft, в частности, см. описание объекта WshRemote; механизм в целом может работать немного по-разному в зависимости от версии WSH (например, могут потребоваться права на создание файлов во временном каталоге на удалённой машине);
удалённые сценарии всегда запускаются с помощью сервера сценариев wscript.exe, причём в пакетном режиме, т.е. подавляется отображение ошибок и запросов сценария; это означает, что использование методов WScript.Echo или WshShell.Popup может привести к непредсказуемым результатам.

Объект WshController создаётся следующим образом:

Set oCtrl = CreateObject("WshController")

Объект WshController имеет единственный метод CreateScript(CommandLine, [MachineName]), который возвращает указатель на объект WshRemote, с помощью которого можно контролировать состояние удалённого сценария и управлять его выполнением. Первый параметр содержит путь к файлу относительно локальной машины (файл может находиться на каком-либо сетевом ресурсе; это делает возможным, работая на одном компьютере, загружать скрипт с другого и выполнять его на третьем компьютере).

Свойства объекта WshRemote:

Status	Состояние асинхронно работающего сценария. Возможные значения: 0 (NoTask) — сценарий не запущен; 1 (Running) — сценарий выполняется; 2 (Finished) — сценарий завершён.
Error	Ссылка на объект WshRemoteError, содержащий информацию об ошибках.

Методы объекта WshRemote:

Execute()	Запускает сценарий.
Terminate()	Прерывает исполнение сценария.

События объекта WshRemote:

Start	Начало выполнения сценария.
Error	Аварийное завершение выполнения сценария.
End	Нормальное или аварийное завершение выполнения сценария.

Свойства объекта WshRemoteError (методов у него нет):

Description	Краткое описание ошибки (может быть пустым).
Line	Номер строки сценария (если его нельзя определить, содержит 0).
Character	Номер символа в строке (если его нельзя определить, содержит 0).
Number	Код ошибки (число).
SourceText	Строка сценария (если её нельзя определить, содержит 0).
Source	Название COM-объекта — источника ошибки.

В качестве примера рассмотрим скрипт lnk.vbs, создающий ярлык на Рабочем столе для всех пользователей:

Set WshShell = CreateObject("WScript.Shell")
PathShortcut = WshShell.SpecialFolders("AllUsersDesktop")
Set Shortcut = WshShell.CreateShortcut(PathShortcut & "\Remote.lnk")
Target = WshShell.ExpandEnvironmentStrings("%windir%\notepad.exe")
Shortcut.TargetPath = Target
Shortcut.Save()

Запустим этот скрипт на удалённой машине \\home:

Set oCtrl = CreateObject("WshController")
Set oScript = oCtrl.CreateScript("C:\Temp\Testing\lnk.vbs", "home")
WScript.ConnectObject oScript, "Remote_" ' подключаемся к событиям
oScript.Execute()
IsQuit = False
While Not IsQuit
    Wscript.Sleep 100
Wend
'========================================================================================
Function Remote_End()
    Wscript.Echo "Выполнение удалённого сценария завершено."
    IsQuit = True
End Function
Function Remote_Error()
    Wscript.Echo oScript.Error.Description
    IsQuit = True
End Function
Function Remote_Start()
    Wscript.Echo "Начато выполнение удалённого сценария."
End Function

См. также статью Рецепты WMI: управление процессами.

Людоговский Александр, 07.02.2009г.

Перейти на главную страничку сайта (список статей, файлы для скачивания)