Loop (файлы и папки)

Loop, FilePattern [, IncludeFolders?, Recurse?]

if A_LoopFileAttrib contains H,R,S ; Пропускать файл, если он H (скрытый), R (только для чтения) или S (системный).
                                   ; Замечание: в строке "H,R,S" не должно быть пробелов.
    continue ; Пропустить этот файл и перейти к следующему.

FileList =
Loop *.jpg
    FileList = %FileList%%A_LoopFileName%`n
Loop, parse, FileList, `n
    FileMove, %A_LoopField%, renamed_%A_LoopField%

; Пример №1
Loop, %A_ProgramFiles%\*.txt, , 1 ; Рекурсия в подпапки.
{
    MsgBox, 4, , Имя файла = %A_LoopFileFullPath%`n`nПродолжить?
    IfMsgBox, No
        break
} 

; Пример №2: вычисляет размер папки, включая файлы во всех её подпапках.
SetBatchLines, -1 ; Выполнять на максимальной скорости.
FolderSizeKB = 0
FileSelectFolder, WhichFolder ; Запрос пользователю на выбор папки.
Loop, %WhichFolder%\*.*, , 1
    FolderSizeKB += %A_LoopFileSizeKB%
MsgBox Размер %WhichFolder% -- %FolderSizeKB% Кб. 

; Пример №3: возвращает файлы, отсортированные по имени (сортировку по дате см. в следующем примере).
FileList = ; Очистить переменную.
Loop, C:\*.*
    FileList = %FileList%%A_LoopFileName%`n
Sort, FileList, R ; Опция R означает сортировку в обратном порядке. Другие опции см. в описании Sort.
Loop, parse, FileList, `n
{
    if A_LoopField = ; Игнорировать пустую строку в конце списка.
        continue
    MsgBox, 4,, Файл номер %A_Index%: %A_LoopField%.  Продолжить?
    IfMsgBox, No
        break
} 

; Пример №4: возвращает имена файлов, отсортированных по дате изменения.
FileList =
Loop, %A_MyDocuments%\Photos\*.*, 1
    FileList = %FileList%%A_LoopFileTimeModified%`t%A_LoopFileName%`n
Sort, FileList ; Сортировать по дате.
Loop, parse, FileList, `n
{
    if A_LoopField = ; Пропустить последний перевод строки (пустую строку) в конце списка.
        continue
    StringSplit, FileItem, A_LoopField, %A_Tab% ; Разбить на две части в месте, где табуляция.
    MsgBox, 4,, Следующий файл (изменён %FileItem1%):`n%FileItem2%`n`nПродолжить?
    IfMsgBox, No
        break
}

; Пример №5: копирует только те файлы, которые новее,
; чем одноимённые им файлы в месте назначения.
CopyIfNewer:
; Переменные CopySourcePattern и CopyDest были заданы в коде, вызвавшем эту подпрограмму.
Loop, %CopySourcePattern%
{
    copy_it = n
    IfNotExist, %CopyDest%\%A_LoopFileName% ; Всегда копировать, если одноимённый файл не существует.
        copy_it = y
    else
    {
        FileGetTime, time, %CopyDest%\%A_LoopFileName%
        EnvSub, time, %A_LoopFileTimeModified%, seconds ; Вычесть время файла-источника из времени файла-приёмника.
        if time < 0 ; Файл-источник новее, чем файл-приёмник.
            copy_it = y
    }
    if copy_it = y
    {
        FileCopy, %A_LoopFileFullPath%, %CopyDest%\%A_LoopFileName%, 1 ; Перезапись при копировании разрешена.
        if ErrorLevel
            MsgBox, Не удалось скопировать "%A_LoopFileFullPath%" в "%CopyDest%\%A_LoopFileName%".
    }
}
Return 

; Пример №6: конвертирует имена файлов, переданные скрипту как параметры командной строки.
; Возвращает длинные имена, полные пути и правильный регистр букв (как в файловой системе).
Loop %0% ; Для каждого файла, брошенного на значок скрипта (или переданного как параметр).
{
    GivenPath := %A_Index% ; Следующий параметр командной строки.
    Loop %GivenPath%
        LongPath = %A_LoopFileLongPath%
    MsgBox Длинное имя и путь в правильном регистре для файла`n%GivenPath%`n`n%LongPath%
}